coretan tentang autocad dan excel

February 28, 2010

[XLS-SVY-02]: Catatan Rumus Excel untuk Juru Ukur (Bagian #2)

Filed under: Excel, Tukang Ukur — Tags: — cadex @ 00:18
Referensi :
Platform : Excel, dengan add in solver
Lokasi File : click di sini

Perhitungan Poligon dengan menggunakan Solver

Program solver harus sudah terinstall, jika akan menggunkan metode ini.

Pada excel 2003, menu ‘Tool’ kemudian pilih ‘Add-Ins’

image

Pastikan bahwa ‘Solver Add-in’ terpilih (checked)

Misal jalur pengukuran poligon adalah :

poligonTerbuka

Berdasarkan data di atas, kemudian disusun atau ditabulasi di excel sebagai berikut:

image

E5=B5+C5/60+D5/3600, kemudian dicopy ke E7 dan E9.

E13=SUM(E3:E11)

F5=$F$13, kemudian dicopy ke F7 dan F9

F5 adalah koreksi sudut dalam satuan derajat yang akan dicari dengan menggunakan solver

G4=R4

G4 adalah azimuth awal dari Q ke R yang dihitung berdasarkan koordinat Q dan R

R4=DEGREES(ATAN2((Q5-Q3),(P5-P3)))+IF(ATAN2((Q5-Q3),(P5-P3))<0,360)

G6=G4+E5+F5-180+IF(G4+E5+F5-180<0,360,IF(G4+E5+F5-180>360,-360)), kemudian dicopy ke G8 dan G10

G6, G8 dan G10 adalah azimuth yang dihitung berdasarkan sudut horizontal dan koreksi sudut

Hasil azimuth di G10, seharusnya adalah sama dengan azimuth di R10. R10 adalah azimuth dari titik tetap S ke T.

Dalam perhitungan solver kondisi G10=R10 akan dipakai sebagai constraint nomer #1.

Solver akan merubah nilai di F13 sampai diperoleh nilai G10=R10.

H13=SUM(H3:H11)

I6=H6*SIN(RADIANS(G6)), kemudian dicopy ke I8

J6=(H6/$H$13)*$J$13, kemudian dicopy ke J8

K6=H6*COS(RADIANS(G6)), kemudian dicopy ke K8

L6=(H6/$H$13)*$L$13, kemudian dicopy ke L8

J13 dan L13 adalah koreksi absis dan ordinat yang akan dicari dengan menggunakan solver.

M7=M5+I6+J6, kemudian dicopy ke M9

N7=N5+K6+L6, kemudain dicopy ke N9

Hasil koordinat di M9,N9 harusnya sama dengan nilai koordinat di P9,Q9.

P9,Q9 adalah koordinat titik fix(tetap) dari titik S.

Kondisi M9=P9 dan N9=Q9 adalah contraint nomer #2 dan #3.

Solver akan merubah nilai di J13 dan L13 sampai diperoleh nilai M9=P9 dan N9=Q9.

S9=–AND(P9=M9,Q9=N9)

nilai S9=1, jika koordinat koordinat di  M9,N9 sama dengan P9,Q9.

Pada menu excel (excel-2003), pilih ‘Tool’ kemudian ‘Solver’.

Set solver seperti gambar di bawah:

image

Perhatikan nilai atau cell di ‘Set Target’, ‘Changing Cells’ dan ‘Constraint’

Jika setting sudah sesuai di atas, click tombol ‘Solve’

Hasilnya adalah hitungan poligon yang sudah terkoreksi, sudut, absis dan ordinatnya

image

~selamat mencoba~

7 Comments »

  1. sangat bermanfaat pak…terima kasih untuk tutorial yang sangat bagus ini….saya tunggu kiriman artikel terbarunya….

    Comment by il_ofik — March 12, 2010 @ 20:39

  2. […] Program (Add-in) solver harus sudah terinstall di excel, sebelum menjalan proses multiple goal seek. Cara menginstall Add-in solver silahkan click di sini. […]

    Pingback by [GEN-PMG-03]: Pemakaian Solver untuk Multiple Goal Seek « coretan tentang autocad dan excel — January 8, 2011 @ 17:54

  3. mas..saya anak teknik sipil tapi sangat minat belajar pengukuran..bisa minta tips nda mas ??

    Comment by hermank — November 13, 2012 @ 15:25

    • tipsnya ikut team survey sekaligus pengolahannya dengan software pemetaan.
      sering saya jumpai surveyor yang hanya bisa survey, tetapi tidak bisa mengolah data dengan komputer

      Comment by cadex — November 13, 2012 @ 21:23

  4. LUAR BIASA..SY SANGAT TERBANTU…SBG SURVEYOR THANKS SO MUCH….

    Comment by FIRMAN RYANTO — January 29, 2015 @ 22:40

  5. masih bingung bagaimana cara mendapatkan hasil azimuth :(
    bisa kah di jelas kan lebih terperinci soalnya saya mahasiswa sipil yang baru belajar mengenai Ilmu Ukur Tanah

    Comment by everlyn — December 3, 2015 @ 21:02

    • kalo mahasiswa teknik sipil tentu pernah menghitung invers tangen di SMA kan? rumusnya didapat dari situ. Angap arah utara sbg sudut nol kemudian ke arah timur menjadi sudut 90 derajat dst

      Comment by cadex — December 19, 2015 @ 10:49


RSS feed for comments on this post. TrackBack URI

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s

Blog at WordPress.com.

%d bloggers like this: