[XLS-SVY-26]: Menghitung Koreksi Koordinat karena Salah Input Koordinat Backsight dan Station dengan Microsoft Excel

Seperti diuraikan pada post sebelumnya bahwa disarankan untuk menyimpan data pengukuruan total sation dalam bentuk data ukuran yang minimal berisi informasi tentang:

  • Tempat berdiri alat dan backsight
  • Tinggi alat dan tinggi target
  • Nama detail
  • Ukuran jarak miring, bacaan sudut horisontal, bacaan sudut vertikal

Dengan informasi di atas, maka jika ada perubahan data atau editing data ukuran misal salah input tinggi alat, tinggi target atau salah input koordinat station dan backsigh dapat dilakukan tanpa harus melakukan pengukuran ulang lagi.

Posting sebelumnya telah diuraikan bagaimana cara mengkonversi data ukuran dari koordinat xyz ke dalam file field book di civil 3d, sedangkan kali ini diuraikan cara menghitung data hasil ukuran koordinat dari total station dengan menggunakan microsoft excel.

Data yang akan diolah adalah data yang saya terima dari surveyoer yaitu berupa data koordinat dalam bentuk XYZ atau lebih tepatnya berformai PENZD (PointNumber, East, North, Z dan Description). Setelah saya gambarkan dalam Civil 3D ternyata posisi koordinat tersebut tidak tepat. Berdasarkan informasi dari surveyornya, ternyata ada salah memasukkan koordinat titik berdiri alat dan koordinat backsight.

Koordinat XYZ yang benar ada dikolom masing FIX_E, FIX_N dan FIX_Z untuk masing-masing station dan backsightnya sehingga perlu dilakukan hitungan koreksi untuk titik SS (sight shot) mulai titik 3 sampai akhir.

Ururutan untuk menghitung koreksi secara garis besar adalah:

  1. Menghitung Jarak dan Sudut dari Station ke Detail (SS).

    Dengan menggunakan koordinat awal (koordinat belum dikoreksi):

  • Hitung Azimut arah station ke backsight (AZ_BS)
  • Hitung Azimuth arah Station ke Foresight / SS (AZ_FS)
  • Hitung sudut horisontal dengan rumus (HZ)
  • Hitung jarak datar dari station ke detail (HD)
  • Hitung beda tinggi dari station ke detail (DH)
  1. Menghitung Koordinat Detail berdasarkan Jarak dan Sudut dari titik berdiri alat (Station)
  • Dengan koordinat fix, Hitung Azimuth arah station ke backsight (AZ_FIX_BS)
  • Hitung Azimuth dari station ke Foresight (SS) (AZ_FIX_FS)
  • Hitung koordinat terkoreksi dengfan rumus:

    X_FIX=X_FIX_STA + HD*SIN(AZ_FIX_FS)

    Y_FIX=Y_FIX_STA + HD*COS(AZ_FIX_FS)

    Z_FIX=Z_FIX_STA+DH

Untuk mempermudah input data data , spreadsheet dibuat menggunakan object table. Detail mengenai keuntungan menggunakan object data silakah dibaca di https://www.excelefficiency.com/excel-table-benefits/

Kolom

Rumus

Keterangan

NO

=ROW()-ROW(tbl_before_adj[[#Headers],[NO]])

Memberi rumus nomer urut secara otomatis. JANGAN DIHAPUS KOLOM INI

PNT,E, N,Z,CODE

 

Input coordinat yang akan dikoreksi

REC

 

Masukkan kode ST : untuk station, BS : untuk backsight dan , SS : untuk sightshot

FIX_E, FIX_N, FIX_Z

 

Masukkan koordinat ST dan BS yang benar (FIX)

ST_E

ST_N

=INDEX([E],MATCH(“ST”,[REC],0))

=INDEX([N],MATCH(“ST”,[REC],0))

Menampilkan koordinat [E] berdasarkan pencarian kata “ST” dalam kolom REC.

Menampilkan koordinat [N] berdasarkan pencarian kata “ST” dalam kolom REC.

BS_E

BS_N

ST_Z

=INDEX([E],MATCH(“BS”,[REC],0))

=INDEX([N],MATCH(“BS”,[REC],0))

=INDEX([Z],MATCH(“ST”,[REC],0))

Menampilkan koordinat [E] berdasarkan pencarian kata “BS” dalam kolom REC.

Menampilkan koordinat [N] berdasarkan pencarian kata “BS” dalam kolom REC.

Menampilkan koordinat [Z] berdasarkan pencarian kata “ST” dalam kolom REC.

AZ_BS

 

=MOD(

DEGREES(

    ATAN2(

        [@[BS_N]]-[@[ST_N]],

        [@[BS_E]]-[@[ST_E]])

)

,360)

Menghitung azimuth dari station ke back sight

Fungsi MOD(….,360) akan otomatis menambahkan 360 derajat jika hasil ATAN2() bernilai negatif

Fungsi DEGRESS() merubah sudah RADIANS hasil fungsi ATAN2()

Fungsi ATAN2() menghitung sudut azimuth dalam unit RADIANS dengan input:

DY = (Y backsight – Y station)

DX= (X backsight – X station)

AZ_FS

 

=IF([@REC]=”SS”,

    MOD(DEGREES(

    ATAN2([@N]-[@[ST_N]],[@E]-[@[ST_E]])),

    360),

0)

Menghitung azimuth dari station ke FS (SS)

Dihitung jika kolom [REC]=”SS”

 

 

 

Jika kolom [REC] tidak sama dengan “SS” isi dengan 0 (nol)

HZ

 

=IF([@REC]=”SS”,

    MOD([@[AZ_FS]]-[@[AZ_BS]],360)

,0)

Menghitung sudut horisontal dihitung dari backsight

Dihitung jika kolom [REC]=”SS”

 

Jika kolom [REC] tidak berisi kode “SS”, isi dengan 0

HD

=IF([@REC]=”SS”,

    SQRT(([@E]-[@[ST_E]])^2+([@N]-[@[ST_N]])^2)

,0)

Menghitung jarak datar dari station ke ss, jika kolom [REC]=”SS”

DH

=IF([@REC]=”SS”,

    [@Z]-[@[ST_Z]],

0)

Menghitung beda tinggi dari station ke SS, jika kolom [REC]=”SS”

ST_FIX_E,ST_FIX_N

BS_FIX_E,BS_FIX_N

ST_FIX_Z

 

Menampilkan koordinat [FIX_E], [FIX_N] berdasarkan pencarian kata “ST” dalam kolom REC.

Menampilkan koordinat [FIX_E], [FIX_N] berdasarkan pencarian kata “BS” dalam kolom REC.

Menampilkan koordinat [FIX_Z] berdasarkan pencarian kata “ST” dalam kolom REC.

AZ_FIX_BS

=MOD(

    DEGREES(

    ATAN2(

    [@[BS_FIX_N]]-[@[ST_FIX_N]],

    [@[BS_FIX_E]]-[@[ST_FIX_E]])

    ),

360)

Menghitung azimuth dari station ke back sight dari koordinat fix

AZ_FIX_FS

=IF([@REC]=”SS”,

    MOD([@[AZ_FIX_BS]]+[@HZ],360)

,0)

Menghitung azimuth dari station ke SS/FS menggunakan sudut horisontal [HZ]

X_FIX

=IF([@REC]=”SS”,

    [@[ST_FIX_E]]+[@HD]*SIN(RADIANS([@[AZ_FIX_FS]])),

[@[FIX_E]])

Menghitung koordinat X terkoreksi, jika kolom [REC]=”SS”

 

Jika bukan “SS”, isi koordinat fix

Y_FIX

=IF([@REC]=”SS”,

    [@[ST_FIX_N]]+[@HD]*COS(RADIANS([@[AZ_FIX_FS]])),

[@[FIX_N]])

Menghitung koordinat Y terkoreksi, jika kolom [REC]=”SS”

 

Jika bukan “SS”, isi koordinat fix

Z_FIX

=IF([@REC]=”SS”,

    [@DH]+[@[ST_FIX_Z]],

[@[FIX_Z]])

Menghitung koordinat Z terkoreksi, jika kolom [REC]=”SS”

 

Jika bukan “SS”, isi koordinat fix

 

==semoga bermanfaat==

2 thoughts on “[XLS-SVY-26]: Menghitung Koreksi Koordinat karena Salah Input Koordinat Backsight dan Station dengan Microsoft Excel

  1. Terima kasih ilmu yang bpk posting sangat bermanfaat.boleh saya download?saya pingin belajar banyak dengan bapak. Terima kasih

Leave a Reply to Sutris Trisno Cancel reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google photo

You are commenting using your Google account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s