[XLS-SVY-11]: Perhitungan rerata dan standard deviasi hasil pengukuran sudut dan jarak dari total station (theodolit)

 

Referensi :  
Platform : Excel
Lokasi File : https://skydrive.live.com/embedicon.aspx/Public/catatan%20juru%20ukur/XLS-SVY-11.zip?cid=7b3122134b7f51a8&sc=documents

Saya mendapatkan data survey hasil pengukuran jaring trilateration kombinasi dengan triangulation dengan menggunakan total station. Data tersebut terdiri dari informasi tentang tempat berdiri alat, tinggi alat, tinggi target, target, bacaan sudut horisontal, bacaan sudut vertikal, jarak datar dan jarak miring.

image

Tulisan kali ini akan saya fokuSkan bagaimana cara menghitung sudut horisontal dan jarak horisontal (HD).

A. Menghitung rata-rata dan standar deviasi sudut horisontal.

Format yang saya pakai untuk menghitung sudut adalah sebagai berikut :

image

[O5] =E5 Nama Target Backsight (BS)
[P5] =A5 Kedudukan Instrument atau station (STN)
[Q5] =E6 Nama Target Foresight (FS)
[R5] =F5+G5/60+H5/3600 Konversi sudur derajat, menit,detik ke derajat desimal, copy rumus ini sampai ke [R12]
[S6] =IF(D6="B",R6-R5+IF(R5>R6,360),R5-R6+IF(R6>R5,360)) menghitung sudut horisontal yaitu bacaan sudut FS dikurangi bacaan sudut BS.

Penting!!!:
Rumus ini berlaku jika urutan pengukuran sudutnya adalah B(Backsight)-B(Foresight)-LB(Foresight)-LB(Backsight)

untuk urutan B(Backsight)-LB(Backsight)-LB(Foresight)-B(Foresight) silahkan dilihat di file attachment.

[S8],[S10],[S12]   dicopy dari rumus di [S6]
[T6] =S6/24 konversi sudut derajat desimal ke derajat-menit-detik dengan menggunakan format time di excel.
set format number di [T6] menjadi [h]° mm’ ss\"
image
untuk menampilkan symbol derajat: tekan tombol ALT, tahan tombol ALT kemudian tekan angka 176 di numeric pad, kemudian lepaskan tombol ALT.

Jika menggunakan laptop, numeric pad akan aktif jika tombol ‘number lock’ diaktifkan. Posisi tombol akan berbeda tergantung merk dan type laptop. Contoh saya menggunakan laptop hp pavilium dv3, tombol number lock diaktifkan dengan menekan bersama-sama tombol Fn+shitf+numlk.

Penting!!!:
Rumus menggunakan format jam ini berlaku jika nilai sudutnya selalu positif

[T8],[T10],[T12]   copy rumus dari [T6]
[U5] =AVERAGE(T6:T12) menghitung sudut rata-rata
[V5] =STDEV(T6:T12) menghitung standar deviasi
    copy rumus [U5:V5] ke [U14:V14]

B. Menghitung rata-rata dan standard deviasi jarak horisontal

Format yang saya pakai untuk menghitung jarak adalah:

image

sebelum mulai perhitungan jarak, perlu didefinisikan ID penggal jarak. Jarak rata2 dan standar deviasi akan dihitung jika mempunya id yang sama. Jika pengukuran jarak dimulai dari station (STN) BMS1 dan target (FS) adalah BMS2 maka ID nya harus  sama dengan pengkuran sebaliknya STN di BMS2 dan FS di BMS1

List ID penggal jarak didefinikan di kolom AC, AD dan AE. Perlu diperhatikan bahwa nama station(STN) dan foresight(FS) harus sama persis, jika tidak maka akan terjadi kesalah perhitungan di rata-rata dan standard deviasi. “BMS1” tidak sama dengan “BMS 1”.

Tips: saat pengolahan data seperti ini, untuk menghindari salah hitung sebaiknya nama (id) titik berupa angka saja tanpa ada karakter.

[AA5] =SUM((((X5=$AD$5:$AD$13)*(Y5=$AE$5:$AE$13)+(Y5=$AD$5:$AD$13)*(X5=$AE$5:$AE$13))=1)*$AC$5:$AC$13) Formula array: setelah menulis rumusnya, akhir dengan  (CTRL+SHIFT+ENTER)
Berfungsi untuk mencari ID penggal garis dari list ID yang sudah didefinisikan di kolom [AC], [AD] dan [AE]
[AA6:AA12] copy rumus dari [AA5]  
[AF5] =AVERAGE(IF($AA$5:$AA$89=AC5,$Z$5:$Z$89)) Formula array: untuk menghitung rata-rata di penggal garis sesuai dengan id di [AC5]
[AG5] =STDEV(IF($AA$5:$AA$89=AC5,$Z$5:$Z$89)) Formula array: menghitung standar deviasi
[AF6:AG13] copy [AF5:AG5]  

==silahkan dicoba==

Advertisements

[GEN-PMG-04]:Menghitung Upah Lembur dengan Excel (Kep Men. NOMOR KEP. 102/MEN/VI/2004)

Referensi : Keputusan Menteri Tenaga Kerja & Transmigrasi NOMOR KEP. 102/MEN/VI/2004:
WAKTU KERJA LEMBUR DAN UPAH KERJA LEMBUR
Platform : Excel
Lokasi File : ada di sini

Mengacu ke pasal 11:

Cara perhitungan upah kerja lembur:

Cara perhitungan upah kerja lembur sebagai berikut :

a. Apabila kerja lembur dilakukan pada hari kerja :
a.1. untuk jam kerja lembur pertama harus dibayar upah sebesar 1,5 (satu setengah) kali upah sejam;
a.2. untuk setiap jam kerja lembur berikutnya harus dibayar upah sebesar 2(dua) kali upah sejam.

b. Apabila kerja lembur dilakukan pada hari istirahat mingguan dan/atau hari libur resmi untuk waktu kerja 6 (enam)
hari kerja 40 (empat puluh) jam seminggu maka :
b.1. perhitungan upah kerja lembur untuk 7 (tujuh) jam pertama dibayar 2 (dua) kali upah sejam, dan jam
kedelapan dibayar 3 (tiga) kali upah sejam dan jam lembur kesembilan dan kesepuluh dibayar 4 (empat) kali upah
sejam.
b.2. apabila hari libur resmi jatuh pada hari kerja terpendek perhitungan upah lembur 5 (lima) jam pertama dibayar
2 (dua) kali upah sejam, jam keenam 3(tiga) kali upah sejam dan jam lembur ketujuh dan kedelapan 4 (empat)
kali upah sejam.

c. Apabila kerja lembur dilakukan pada hari istirahat mingguan dan/atau hari libur resmi untuk waktu kerja 5 (lima)
hari kerja dan 40 (empat puluh) jam seminggu, maka perhitungan upah kerja lembur untuk 8 (delapan) jam
pertama dibayar 2 (dua) kali upah sejam, jam kesembilan dibayar 3(tiga) kali upah sejam dan jam kesepuluh dan
kesebelas 4 (empat) kali upah sejam.

Pada contoh hitungan kali ini akan menggunakan asumsi 5 (lima) hari kerja dan 40 jam seminggu. Sehingga dari pasal tersebut yang digunakan adalah ayat a.2 dan c.

Persiapan dan tahapan perhitungan:

1. Buat list hari libur Nasional di sheet tersendiri.
Contoh List hari libur Nasional Tahun 2011 (pada contoh, cuti bersama tidak saya masukkan)
image
Block (select/pilih) range A1:A15, kemudian dari menu [insert], pilih [Define].
setelah diklik [OK], maka ‘Defined Name Range’ dengan nama [LiburNasional] sudah terdefinisi di workbook aktif
2. Contoh spreadsheet dengan jumlah jam kerja yang akan dihiutung jam kerjanya:
imageAgar di kolom [A], ditampilkan nama hari dalam bahasa indonesia, ganti format number di kolom [A] menjadi:
imagedi cell [C3], masukkan rumus
=SUMPRODUCT((LiburNasional=A3)*1)+(WEEKDAY(A3,2)>5)
a. Keterangan dari rumus SUMPRODUCT((LiburNasional=A3)*1) adalah, apabila tanggal di cell [A3] adalah libur nasional, maka akan menghasilkan nilai 1 (satu).

b. Sedangkan WEEKDAY(A3,2)>5 akan TRUE atau bernilai 1, jika tanggal di [A3] adalah hari Sabtu atau Minggu.

Jika kondisi a dan b dijumlahkan , maka untuk hari libur akan bernilai > 0, sedangkan untuk bukan hari libur bernilai = 0.

Copy rumus di [A3] ke bawah

3. Kolom [D2:G2] adalah angka faktor pengali lembur yang telah ditentukan sesuai dengan Pasal 11 ayat a.2 dan c.
Sedangkan kolom [H] adalah hasil dari penjumlahan faktor pengali lembur dari kolom [D2:G2]
4. Menghitung faktor pengali lembur di hari kerja biasa (bukan hari libur)
Asumsi 5 (lima) hari kerja dan 40 jam seminggu, maka jam kerja tiap hari yang tidak dihitung lembur adalah 8 jam/hari
Misal:
[B3]= jumlah jam kerja/hari
[C3]=0 untuk hari kerja, dan [C3]>0 untuk hari libur.
[D2],[E2],[F2] dan [G2]=faktor pengali 1.5, 2.0, 3.0 dan 4.0Maka Pasal 11 ayat a jika ditulis dalam rumus Excel:

a. Apabila kerja lembur dilakukan pada hari kerja =IF(C3=0,ke a.1,ke langkah 5)
a.1. untuk jam kerja lembur pertama harus dibayar upah sebesar 1,5 (satu setengah) kali upah sejam; IF(B3>8,1)*D$2
Rumus di gabung
=IF(C3=0,IF(B3>8,1))*D$2
a.2. untuk setiap jam kerja lembur berikutnya harus dibayar upah sebesar 2(dua) kali upah sejam =IF(C3=0,IF(B3>9,B3-9))*E$2
5. Pasal 11 ayat c:

c.1. perhitungan upah kerja lembur untuk 8 (delapan) jam pertama dibayar 2 (dua) kali upah sejam =MIN(B3,8)*E$2
rumus MIN(B3,8) untuk antisipasi, jika seandainya ada yang masuk di hari libur tetapi kurang dari 8 jam
c.2. jam kesembilan dibayar 3(tiga) kali upah sejam =IF(B3>=9,1)*F$2
c.3. jam kesepuluh dan
kesebelas 4 (empat) kali upah sejam
=IF(B3>=10,B3-9)*G$2
6. Rumus di [D3], [E3], [F3] dan [G3]
[D3]=IF(C3=0,IF(B3>8,1))*D$2
[E3]=IF(C3=0,IF(B3>9,B3-9),MIN(B3,8))*E$2  ‘gabungan fungsi a.2 dan c.1
[F3]=IF(C3>0,IF(B3>=9,1))*F$2
[G3]=IF(C3>0,IF(B3>=10,B3-9))*G$2
7. [H3]=SUM(D3:G3)
8. Jika upah perjam adalah 15000, maka [I3]=15000. Rumus di
[J3]=H3*I3
9. Copy rumus di [D3:J3] ke bawah untuk menghitung upah lembur di hari yang lain…
10. Pengecekan rumus perhitungan
Masukkan rumus di [K3]
=B3=(SUMPRODUCT(D3:G3,1/$D$2:$G$2)+IF(C3=0,MIN(B3,8)))
Kemudian copy ke bawah.
Jika nilai-nilai dikolom [K], bernilai TRUE, maka perhitungan faktor pengali lembur sudah benar.
11. Jika ingin disederhanakan, rumus di [H3] bisa dirubah menjadi (revisi.01 14 Februari 2011)
[H3]=N(IF(C3=0,IF(B3>8,1.5+(B3-9)*2),IF(B3>0,MIN(B3,8)*2+IF(B3>=9,3)+IF(B3>=10,(B3-9)*4))))

==silahkan mencoba==
Untuk 6 (enam) hari kerja silahkan click di sini