[XLS-SVY-25]: Menghitung Jarak, Sudut dan Beda Tinggi dari data Pengukuran Total Station Format X,Y, Z untuk diolah di Civil 3D (Bagian-01)

Saya pernah menerima data survey dari surveyor hasil download total station dalam format nama Titik, X, Y, Z (PXYZ) tanpa menyertakan data mentah atau raw data yang berisi informasi tempat berdiri alat, backsight, jarak miring, sudut vertikal, sudut horisontal, tinggi alat dan tinggi target. . Contoh data yang aku terima:

Format hasil download berupa titik, X, Y dan Z mempunyai kelemahan antara lain:

  1. Jika ada koreksi data ukuran seperti data jarak, sudut, tinggi alat atau tinggi target maka otomatis koordinat tidak bisa dihitung ulang.
  2. Tidak bisa dilakukan pengolahan data poligon atau network adjustment.

Agar data bisa diolah lebih lanjut di civil, maka data di atas perlu dimodifikasi dan diberi data tambahan sebagai berikut:

  1. Rubah nama titik menjadi angka bulat karena civil 3d tidak bisa menerima nama titik dalam selain angka bulat. Nama titik menjadi dijadikan point description dalam civil 3d. Format titik menjadi PENZD atau (PointNumber, East, North, Elevation dan Description)
  2. Menambahkan koordinat tempat berdiri alat dan koordinat backsight yang nantinya akan digunakan untuk menghitung sudut horisontal
  3. Setelah data yang terdiri sudut horisontal, jarak dan beda tinggi sudah dihitung, maka dilakukan konversi ke format autodesk fieldbook (fbk) untuk selanjutnya diproses dengan civil 3d dengan menggunakan tool civil 3d survey.

Format data setelah diedit menjadi:

 

Kolom

Keterangan

A

Infomasi keterangan job atau job-id

B

Informasi urutan tempat berdiri alat, atau setting alat

C

Kode titik: ST: Stasiun atau tempat berdiri alat BS: Backsight bidikan belakang atau orientasi SS: Sightshot bidikan detail

D,E,F,G

Berturut-turut Nama titik, X, Y , Z

H

Point Number dalam format angka bulat. Titik detail (SS) dengan format angka misal 7200001 artinya titik nomer 1 saat alat berdiri di station 72. Dengan cara pengkodean SS seperti di atas, maka tiap titik detail bisa dilacak tempat berdiri alatnya

 

Tahapan berikutnya adalah untuk menghitung kembali jarak dan sudut horisontal dari data koordinat:

 

Cell

Rumus

Keterangan Rumus

[I4]

=IF(LEN(D4)=0,”-“,LOOKUP(9^9,$B$4:$B4,E$4:E4))

Jika cell [D4] kosong atau panjang charactes (Len(D4)=0), maka isikan dengan tanda “-” Jika [D4] ada isinya, maka cari angka di kolom [B] atau kode angka tempat berdiri alat, kemudian jika ketemu diambail nilai koordinat X nya dari kolom [E]

[J4] [K4]

=IF(LEN($D4)=0,”-“,LOOKUP(9^9,$B$4:$B4,F$4:F4)) =IF(LEN($D4)=0,”-“,LOOKUP(9^9,$B$4:$B4,G$4:G4))

Sama dengan keterangan di atas tapi untuk mengambil nilai Y dari kolom F dan Z dari kolom G

[L4]

=IF(OR(C4=”ST”,LEN($D4)=0),”-“, IF($C4=”BS”, MOD(DEGREES(ATAN2(($F4-$F3),($E4-$E3))),360) ,L3))

Jika C4 sebagi tempat berdiri alat (ST) atau D4 kosong, maka tidak dihitung azimuth atau (“-“) Jika C4 sebagai titik bidikan belakang atau backsight (BS) Maka dihitung azimuth dari ST ke BS Jika kode SS yaitu kode selain ST dan BS, maka azimuth mengikuti hitungan baris sebelumnya

[M4]

=IFERROR(IF(C4=”SS”, MOD(DEGREES(ATAN2(F4-J4,E4-I4)),360) ,”-“),”-“)

Jika C4 sebagai titik detail (SS) Hitung azimuth dari ST ke SS Jika bukan kode SS, isikan dengan “-“

[N4]

=IFERROR(IF(C4=”SS”,MOD(M4-L4,360),”-“),”-“)

Jika C4 sebagai titik detail, hitung sudut horisontal dengan mengurangkan sudut azimut detail ke azimut statiion (M4-L4)

[O4]

=IFERROR(IF(C4<>”ST”,SQRT((E4-I4)^2+(F4-J4)^2),”-“),”-“)

Hitung jarak horisontal dari ST ke detail (SS)

[P4]

=IFERROR(G4-K4,”-“)

Menghitung beda tinggi ST ke SS

[Q4]

=””””&D4&””””

Merubah format nama titik menjadi diapit tanda ” agar bisa diproses di FBK

[R4]

=LOOKUP(“ZZZzzz”,A$4:A4)

Copy kode JOB

[I4:R4]

 

Copy rumus di range tersebut ke bawah sampai akhir data

Pada tahap ini jarak datar, sudut horisontal dan beda tinggi sudah didapatkan. Tahap berikutnya adalah merubah data di atas menjadi FBK

 

Cell

Rumus

Keterangan Rumus

[T4]

=INDEX($D$22:$D$24,MATCH($C4,$C$22:$C$24,0))

Merubah kode di kolom C menjadi kode di FBK

[U4] [V4] [W4] [U4:W4]

=IF($C4<>”SS”,”-“,TRUNC($N4)) =IF($C4<>”SS”,”-“,TRUNC(($N4-TRUNC($N4))*60)) =IF($C4<>”SS”,”-“,3600*($N4-TRUNC($N4))-60*TRUNC(($N4-TRUNC($N4))*60))

Mengambil nilai derajat dari hitungan sudut dari [N4] Mengambil nilai menit dari hitungan sudut dari [N4] Mengambil nilai detik dari hitungan sudut dari [N4] hasil konversi sudut dari desimal menjadi derajat-menit-detik

[X4] [X4]

=IF(C4<>”SS”,”-“, U4&”.”& TEXT(V4,”00″)& TEXT(INT(W4),”00″)& INT(MOD(W4,1)*10000))

Jika C4 tidak bidikan detail (SS), maka isikan dengan “-“, tetapi jika SS, maka Ambil nilai derajatnya diikuti dengan simbol “.” Ambil nilai menit dengan format dua digit “00” Ambil angka bulat dari nilai detik format dua digit “00” Ambil nilai desimal dari nilai detik jika ada. Hasil konversi suder derajat-menit-detik menjadi format d.mmss00

[Y4]

=REPT(TEXT(O4,”0.0000″),$C4=”SS”)

Rubah nilai jarak menjadi text format 4 digit desimal

[Z4]

=REPT(TEXT(P4,”0.0000″),$C4=”SS”)

Rubah nilai beda tinggi menjadi text format 4 digit desimal

[AA4]

=T4&” “&H4&REPT(” 0.0000 “,C4<>”SS”) & REPT(” “&X4&” “&Y4&” “&Z4&” “&Q4,C4=”SS”)

Rubah data menjadi format FBK

[AA3]

PRISM 0.000

Set tinggi target menjadi 0.000 meter

[T4:AA4]

 

Copy rumus di range tersebut dampai akhir data

Pada tahap ini, file ukuran sudah dirubah menjadi format FBK dan siap untuk di proses di civil 3d. Pilih range [AA3:AA17], kemudian paste di notepad lalu simpan dengan ekstensi *.fbk

 

((Lanjut ke Bagian-2))

Advertisements

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out /  Change )

Google photo

You are commenting using your Google account. Log Out /  Change )

Twitter picture

You are commenting using your Twitter account. Log Out /  Change )

Facebook photo

You are commenting using your Facebook account. Log Out /  Change )

Connecting to %s