Referensi	:	Mengolah Gambar Cross Section di Civil 3D
Platform	:	Excel
Lokasi File	:

Pada tulisan sebelumnya di Mengolah Gambar Cross Section di Civil 3D, telah dijelaskan tahapan-tahapan pengolahan gambar cross section di civil3D dengan data yang bersumber dari file cross section dalam bentuk AutoCAD.

Adakalanya data yang diterima berupa table jarak dan elevasi dalam format excel. Data format seperti ini biasanya didapat dari pengukuran dengan waterpass atau bisa juga dari pengukuran theodolit atau total station, tetapi sudah dikonversikan ke data jarak dan elevasi (cross section).

Contoh data yang akan dibuat grafik cross sectionnya adalah:

Hasil grafik yang akan dibuat:

Jarak Existing	Jarak (offset) yang dihitung dari centerline cross section, ke kiri jarak ditulis dengan angka negatif dan ke kanan dengan angka positif.
Elevasi Existing	Elevasi (tinggi) hasil survey existing
Jarak Design Template	Jarak (offset) finished cross section (offset design berdasarkan design criteria/parameter design)
Elevasi Design Template	Elevasi (tinggi) finished elevation. (elevasi berdasrkan design criteria/parameter design)

1. Parameter Design

contoh parameter design yang dipakai di cross section ini adalah:

[B7]	:	=$B6*ABS(B5)+$C2
		Elevasi design dihitung dari elevasi centerline ke kiri 2 meter dengan kemiringan –2%
[C7]	:	=$C6*ABS(C5)+$C2
		Elevasi design dihitung dari elevasi centerline ke kanan 2 meter dengan kemiringan –2%
[B8], [C8]	:	slope ke elevasi existing atau istilah di civil 3D disebut sebagai catch point.

2. Menghitung offset, elevasi catch point di kiri dan kana cross section.

Rumus dasar yang dipakai adalah persamaan garis y=mx+c dengan mencari titik potong antar garis design dengan garis existing. Koordinat y adalah elevasi, x adalah offset, sedangkan m adalah gradien garis dan c adalah konstanta garis.

Jika gradien design (md) , konstanta garis design (cd), gradien existing (me), konstanta garis existing (ce) , maka titik potong garis dapat dirumuskan menjadi

xt=(ce-cd)/(md-me) ; yt=md*xd+cd

xd: absis (offset) design;  xt: offset catch point, yt: elevasi catch point

Gradien ( m ) dan konstanta ( c ) dihitung dengan menggunakan rumus:

m=(y2-y1)/(x2-x1) ; c = y1-mx1 atau c = y2-mx2

x1,y1 : koordinat awal garis; x2:y2: koordinat akhir garis.

Tahapannya adalah sebagai berikut:

2.1.		Menghitung md dan cd
	[I5]	=1/B8 menghitung gradien (md)  ‘cross section design kiri’. Copy rumus di [I5] ke [J5] untuk menghitung gradien cross section sebelah kanan
	[I6]	=B7-I5*B5 menghitung konstanta (cd) garis sisi kiri, copy rumus di [I6] ke [J6] untuk menghitung sisi kanannya.
		dari tahapan di atas, maka akan terbentuk dua persamaan garis yaitu persamaan garis catch point sebelah kanan dan sebelah kiri.  Misal persamaan garis kiri dinamakan ‘garis-kiri’, sedangkan persamaan garis kanan dinamakan ‘garis-kanan’, maka persamaan garis-kiri dan garis-kanan akan dicari titik potongnya dengan persamaan garis sepanjang rangkain garis (polylines) existing. Pada contoh di atas, persamaan garis sepanjang polyline (‘garis-existing’) adalah sebanyak 9 buah persamaan garis.
2.2.		Menghitung gradien dan konstanta garis sepanjang polyline existing (me dan ce). Buat tabel seperti ini:
	[U4]	=B5
	[U5]	=B7
	[V4]	=0
	[V5]	=V5
	[W4]	=C5
	[W5]	=C7
	[T6]	=IF(U2-T2=0,0,(U3-T3)/(U2-T2)) menghitung gradien existing (me), jika U2-T2=0, maka gradiennya bernilai nol copy rumus [T6] sampai ke [T6:AB6] untuk menghitung gradien (me) sepanjang polyline existing
	[T7]	=T3-T6*T2 menghitung konstanta garis (ce), copy rumus [T7] sampai ke [T7:AB7], untuk menghitung ‘ce’ sepanjang polyline existing
2.3.		Menghitung titik potong garis design dan existing
	[T8]	=IF(OR($I5-T6=0,$J5-T6=0),0,IF(T2<=0,(T7-$I6)/($I5-T6),(T7-$J6)/($J5-T6)))
		xt=(ce-cd)/(md-me) Jika $I5-T6=0 atau $J5-T6=0 (md-me=0), maka xt=0. Jika T2<=0 (sisi kiri cross section), maka xt=(T7-$I6)/($I5-T6) >> gradien dan konstanta design kiri, jika tidah, maka (T7-$J6)/($J5-T6) >> gradien dan konstanta design kanan  Copy rumus [T8] ke [T8:AB8] untuk menghitung titik potong sepanjang polyline existing
2.4.		Cek titik potong (xt) apakah berpotongan di sepanjang polyline existing
	[T9]	=AND(T8>=T2,T8<U2) Jika [T8] (xt) terletak di antara koordinat x (offset) [T2] dan [U2], maka [T9]=TRUE atau xt terletak di polyline existing. Copy rumus di [T9] ke [T9:AB9]  Tabel di excel sampai tahap ini adalah: Dari hasil cek perpotongan garis design dengan existing, maka catch point sebelah kiri memotong di offset -4.42m dan sebekah kanan di 2.69
2.5.		Mengambil koordinat catch points
		Tabel pada tahap 2.1, nilai xt dan yt masih kosong. Untuk contoh di atas, bisa saja dimasukkan nilai [I7]=T8 dan [J7]=Y9, tetapi perlu dipertimbangkan apabila ada perubahan jarak atau elevasi baik di elevasi design ataupun existing atau ada penambahan data existing, maka posisi xt kiri dan kanan tidak lagi di [T8] dan [Y9]  Untuk mengantisipasi kemungkinan seperti ini bisa dilakukan dengan menggunakan fasilitas range dinamis. Misalkan ada pengurangan data di [AC2] dan [AC3], maka range Jarak Existing yang semula di [T2:AC2] harus berubah menjadi [T2:AB2] Cara membuat range dinamis adalah :
	[S2]	=MAX(NOT(ISBLANK($T$2:$BG$2))*$T$1:$BG$1) saat menulis rumus di atas akhir dengan CTRL+SHIFT+ENTER rumus ini akan menghitung banyaknya data offset (jarak) yang dimasukkan di baris T2:BG2  Nilai ini akan berubah-rubah sesuai dengan banyaknya offset yang diinput. Dengan menggunakan fungsi =OFFSET() di excel, maka bisa dibuat named range dinamis sesuai dengan perubahan nilai di [S2]. Dari menu excel, pilih ‘Insert’ >> ‘name’ >> ‘define’. masukkan nama named range dan refer to sbb:
	Existing_Jarak	refer to =OFFSET($T$2,,,,$S$2) Membuat range dimulai dari $T$2 melebar (width) ke kanan sepanjang nilai di $S$2
	Existing_Elevasi	refer to =OFFSET(Existing_Jarak,1,0) Membuat range 1 (satu) baris di bawah range Existing_Jarak
		Jika named range sudah didefinisikan, masukkan rumus di [I7] dan [J7]
	[I7]	=MIN((Existing_Jarak<0)*OFFSET(Existing_Jarak,6,0)*OFFSET(Existing_Jarak,7,0)) akhiri rumus dengan  CTRL+SHIFT+ENTER
	[J7]	=MAX((Existing_Jarak>0)*OFFSET(Existing_Jarak,6,0)*OFFSET(Existing_Jarak,7,0)) akhiri rumus dengan  CTRL+SHIFT+ENTER
	[I8]	=I5*I7+I6 copy rumus [I8] ke [J8]
	[T4]	=I7 copy [T4] ke [T5]
	[X4]	=J7 cpy [X4] ke [X5]
2.6		Membuat Grafik Cross Section
		Sebelum grafik dibuat, range dinamis untuk korodinat (offset, elevasi) design harus dibuat terlebih dahulu.
	[S4]	=MAX(NOT(ISBLANK($T$4:$BG$4))*$T$1:$BG$1) akhiri rumus dengan  CTRL+SHIFT+ENTER kemudian buat named range :
	Design_Jarak	Refer To =OFFSET($T$4,,,,$S$4)
	Design_Elevasi	Refer To =OFFSET(Design_Jarak,1,0)
	Label_Jarak_Design	Refer To =Design_Elevasi*0-1
	Label_Jarak_Existing	Refer To =Existing_Elevasi*0-1

Dari menu ‘Insert’ >> ‘Chart’, kemudian pilih type chart XY (Scattered) connected by lines:

Click ‘Next’

Click Tab ‘Series’, kemudian click ‘Add’

Isikan di baris Name, X Values dan Y values, seperti gambar di bawah:

Click ‘Add’

kemudian isikan Name=’100′!$P$4; X Values=’100′!Design_Jarak; Y Values=’100′!Design_elevasi

Click ‘Add’

dengan cara yang sama masukkan berturut-turut

Name=”Offset Existing”; X Values=’100′!Existing_Jarak; Y Values=’100′!Label_Jarak_Existing

Name=”Offset Design”; X Values=’100′!Design_Jarak; Y Values=’100′!Label_Jarak_Design

Graphic kira-kira akan terlihat seperti ini:

Dengan memahami format chart, kira-kira bisa dihasilkan chart sebagai berikut:

Hitungan Cut Area dan Fill Area bersambung ke post berikutnya……

• Excel